用ASP+XML打造留言本

IT/科技 asp

 

一、读者指引
读者指引帮助你掌握本文的梗概。以免你看了大半才明白这编文章不适合你,给你造成视觉污染。

如果你正在用ASP+XML写一些程序,或者你正在学XML那就值得一看。

阅读本文须具备的知识,对ASP有基本的了解,对XML和DOM有基本了解,如果你不了解那么你通过学习本文基本上能够
撑握ASP+XML和DOM的应用,并能根据本文范写出自已更高级的ASP+XML程序。

二、基本思想

本文思想是基于用ASP和DOM来读取和存储XML数据,并利用XML数据来存储留言信息,达到同用数据库存储数据的功
能。

三、XML留言本的优势

或许你会问用ASP+TXT文本也可以达到不用数据库实上留言的功能,不错确实能够做到,而且网上也有很多这样的留
言本免费下载,但这里我要讲一下ASP+XML的优越性。

1、XML+ASP比ASP+TXT速度要快。可能你也发现当TXT文件很少时速度出奇的快,但是随着留言信息的增加TXT文本
变大,速度却又是出奇的慢这就是ASP+TXT的弱点。当然我不能说ASP+XML就一定是出奇的快,但是比起AS
P+TXT来说是快了许多,当然随着留言信息的增加XML文本增大速度也下降很快,但是比起TXT来说就还是好了许多
(这一点可以从WAS测试证明读者可以自行测试),当然ASP+XML比不上数据库,因为数据库对查询做了特别的优
化,而XML只是纯文本,在ASP建立对像是要把XML数据全部读入内存中,如果数据量大的话可想而知速度会慢下来。
那你也许会问那我什么时候用关系数据库存储数据,又什么时候用XML存储数据呢?我这里也顺便提一下,就是当数据比较
复杂无规率时用XML数据比较合适,还有就是你打算这些数据要在不同的操作系统上读取运用时那就是XML大显身手的时候
了。如果你是普通的数据那么不到关键时刻或不支持数据库的空间时还是不要用XML文件来存储数据为好。
2、XML数据的易读取性,TXT文本是比较难操作的,我们必须一行一行的读取判断,而且很多功能无法实上,只能编
制比较简单的留言本,而XML数据则不同了,利用DOM可以轻易的访问每一个节点,而不是TXT那些烦人的Readline()
Witeline()了,我们可以随意的加入删除更新某一个我们感兴趣的节点,利用ASP或者JS或者数据岛都可以轻松实上这一
点,当然我这里为发考虑兼容性,用了ASP来读取XML数据,而没有用数据岛来读取节点数据(因为只有IE5以上版本才
支持数据岛技术)而用ASP来实上就不存在这些问了因为客户得到的是HTML文件。

 3、XML数据夸操作系统性,只要我们把这些数据存储为XML那么这些数据就能被应何基它语言或系统所识别,而不用做
应何改动。TXT显然不具备这些性能。例如我们在网上的留言信息可以直接被被转换成wap格式在手机上显示。

四、建立存储留言信息的XML文件(List.xml)
我们这里不打算使用DTD,因为我们这是我们自已编制并测试通过的XML数据,所以不需要DTD来验证(如果你对
此感兴趣当然可以加一个这不影响程序的运行)。现在我们来看看建立一个留言本的基本要素

0、留言ID号--定义为<id>

1、用户名我们--定义为<username>

2、来自那里们--定义为<fromwhere>

3、留言时间定--义为<Posttime>

4、用户主页定--义为<homepage>

5、用户的信箱--定义为<email>

6、留言内容定--义为<text>

当然以上不是必须的读者可以自行命名并加减相关标签,把它们组合起来就得到List.xml的文件了

<?xml version="1.0" encoding="gb2312"?>
<site>
  <NewList>
<list>
<id>1</id>
<username>苛子</username>
<fromwhere>中国广州</fromwhere>
<Posttime>01-4-23 18:26:56</Posttime>
<homepage>http://page2000.xiloo.com</homepage>
<email>lucaihui@cmmail.com</email>
<text>这是我的第一个XML文件</text>
</list>
  </NewList>
</site>


注意:必须加上encoding="gb2312"否则会报错为非法字符,因为XML默认不支持中文。<site>为根节点<NewList>
<ist>等为子节点。对这个文件的意思我就不多说了大家也应该看的明白了。接下来就是我们如何来显示它了。

五、建立显示XML数据的ASP文件(index.asp)
这个文件要实现的功能就是读取并显示XML数据,首先创建一个XML对像然后把XML读入内存中,利用DOM分离出我们所
要的数据。

<%
strSourceFile = Server.MapPath("/") & "\List.xml"
'获取XML文件的路径这里根据你的虚拟目录不同而不同
Set objXML = Server.CreateObject("Microsoft.FreeThreadedXMLDOM")
'以自由线程创建一个XML对像
objXML.load(strSourceFile)'把XML文件读入内存
Set objRootsite = objXML.documentElement.selectSingleNode("NewList")
'选取NewList节点
%>
<html>
<head>
<title>留言本</title>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<style type="text/css">
<!--
td { font-family: "宋体"; font-size: 9pt; text-decoration: none}
a { font-family: "宋体"; font-size: 9pt; color: #0066CC; text-decoration: none}
a:hover { color: #FF6600; text-decoration: underline}
-->
</style>
</head><body bg>
<table width="80%" border="0" cellspacing="1" cellpadding="4" align="center" bg>
<tr bg>
<td colspan="2"><font >留言溥 <a href="PostNew.asp"><font color=#FFFFFF>写新留言
</font></a></font></td>
</tr>
<%
PageSize =10'假设每页显示10条留言
AllNodesNum =objRootsite.childNodes.length-1
'获取子节点数据(因为是从节点数从0开始的所最大子节点数要减1)
PageNum=AllNodesNum\PageSize+1'算出总页数
PageNo=request.querystring("PageNo")
if PageNo="" then'如果是每一次获得页面则定位到每一页显示最新的留言
PageNo=PageNum
end if
StarNodes=PageNo*PageSize-1'获得起始节点
EndNodes=(PageNo-1)*PageSize'获得结束节点
if EndNodes<0 then
EndNodes=0
end if
if StarNodes>AllNodesNum then'判断起始节点数是否超过总的节点数
EndNodes=EndNodes-(StarNodes-AllNodesNum)
'如果超过则结束节点要减去(StarNodes-AllNodesNum)的差值否则下标会超界出错
StarNodes=AllNodesNum
end if
if EndNodes<0 then
EndNodes=0
end if
while StarNodes>=EndNodes
'从结束节点到超始节点之间读取节点数据
username = objRootsite.childNodes.item(StarNodes).childNodes.item(1).text
'获得用户名
fromwhere = objRootsite.childNodes.item(StarNodes).childNodes.item(2).text
'获得用户来自那里
Posttime = objRootsite.childNodes.item(StarNodes).childNodes.item(3).text
'获得留言时间
homepage = objRootsite.childNodes.item(StarNodes).childNodes.item(4).text
'获得用户主页
email = objRootsite.childNodes.item(StarNodes).childNodes.item(5).text
'获得用户Eamil
text = objRootsite.childNodes.item(StarNodes).childNodes.item(6).text
'获昨留言内容

'*****************************************************************************
'这里使作了XML的DOM来读取数据,显然objRootsite对像所对应的节点为<NewList>
' objRootsite.childNodes.item(StarNodes)所对应的节点就是<list>节点因为不至一个<list>节点所以用了item()
来识别当前节点数据,随着StarNodes的递减<list>节点根着往上移一个个读取<list>节点数据。
'objRootsite.childNodes.item(StarNodes).childNodes.item(1).text所对应的节点为具体的每个节点的文本值,这里
(1)所对应的就是username用户名(因为<list>节点的子节点才是我们真正所要的)
'******************************************************************************

text = replace(text,chr(13),"<br>")
'替代回车
text = replace(text,chr(32)," ")
'替代空格
%>
<tr bg>
<td width="21%" height="94" valign="top">姓名:<%=username%><br>
来 自:<%=fromwhere%><br>
</td>
<td width="79%" height="94" valign="top"> | <a href="<%=homepage%>" target=_blank title="<%=username%
>的主页">主页</a>
| | <a href="mailto:<%=email%>" title="给<%=username%>写信">信箱</a> | |<font >
留言时间:<%=Posttime%> </font>|
<hr>
<%=text%> </td>
</tr>
<tr bg>
<td colspan="2"> </td>
</tr>
<%
StarNodes=StarNodes-1
wend
set objXML=nothing
%>
<tr bg>
<td colspan="2"> 共有&lt;<%=PageNum%>&gt;页
<%
if cint(PageNo)<>PageNum then'分页
response.write "<a href='index.asp?PageNo="&(PageNo+1)&"'>上一页</a>"
end if
if cint(PageNo)<>1 then
response.write "<a href='index.asp?PageNo="&(PageNo-1)&"'>下一页</a> "
end if
%>
</td>
</tr>
</table>
</body>
</html>

六、建立写新留言程序(PostNew.asp)
这个文件要实现的功能就是写入新的XML节点,首先创建一个XML对像然后把XML读入内存中,利用appendChild()方法
加入我们生成的XML节点。

<%
username=request.form("username")
if username<>"" then
fromwhere =request.form("fromwhere")
homepage =request.form("homepage")
email =request.form("email")
text =request.form("text")
text =replace(text,"<","&lt;")
Posttime =now()
strSourceFile = Server.MapPath("/") & "\List.xml"
'获取XML文件的路径这里根据你的虚拟目录不同而不同
Set objXML = Server.CreateObject("Microsoft.XMLDOM")
'创建XML对像
objXML.load(strSourceFile)
'把XML文件读入内存中
Set objRootlist = objXML.documentElement.selectSingleNode("NewList")
'选取<NewList>节点
if objRootlist.hasChildNodes then
'判断<NewList>是否有子节点(因为如果是每一次<NewList>是没有子节点的,
’ 如果不加判断在第一次运得时就会报错
id = objRootlist.lastchild.firstchild.text+1
'这里获得将要插入子节点的ID号,其ID号为<NewList>的最后一个子节点(lastchild)的第一个子节点(firstchild)
的ID号加1(这里我们按照关系型数据库的ID号来递增)
else
'如是没有字子节点则是第一次留言ID号设为1
id=1
end if
brstr=chr(13)&chr(10)&chr(9)
'为了插入XML文件中的节点换行空格排列整齐
’(当然你也可以不用这样只是为了XML数据好看而以)
XMLnode=brstr&"<list>"&brstr & _
"<id>"&id&"</id>"&brstr & _
"<username>"&username&"</username>"&brstr & _
"<fromwhere>"&fromwhere&"</fromwhere>"&brstr & _
"<Posttime>"&Posttime&"</Posttime>"&brstr & _
"<homepage>"&homepage&"</homepage>"&brstr & _
"<email>"&email&"</email>"&brstr & _
"<text>"&text&"</text>"&brstr & _
"</list>"&chr(13)
'根据得到的数据建立XML片段
set objXML2=Server.CreateObject("Microsoft.XMLDOM")
'建立一个新XML对像
objXML2.loadXML(XMLnode)
'把XML版片段读入内存中
set rootNewNode=objXML2.documentElement
'获得objXML2的根节点
objRootlist.appendChild(rootNewNode)
'把XML片段插入到List.xml中
objXML.save(strSourceFile)
'存储lsit.xml文件(因为不存储List.xml只在内存中更新了)
set objXML=nothing
set objXML2=nothing
response.write "谢谢您的留言"
response.end

end if
%>
<html>
<head>
<title>Untitled Document</title>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<style type="text/css">
<!--
td { font-size: 9pt}
-->
</style>
</head>
<body bg>
<table width="80%" border="0" cellspacing="1" cellpadding="4" align="center" bg>
<form action="PostNew.asp" method="post" name="form1">
<tr bg>
<td colspan="2"><font >新留言</font></td>
</tr>
<tr bg>
<td width="19%" align="right">姓 名:</td>
<td width="81%">
<input type="text" name="username">
** </td>
</tr>
<tr bg>
<td width="19%" align="right">来 自:</td>
<td width="81%">
<input type="text" name="fromwhere" value="中国">
</td>
</tr>
<tr bg>
<td width="19%" align="right">主 页:</td>
<td width="81%">
<input type="text" name="homepage" value="http://">
</td>
</tr>
<tr bg>
<td width="19%" align="right">Email:</td>
<td width="81%">
<input type="text" name="email">
</td>
</tr>
<tr bg>
<td width="19%" align="right" valign="top">内容:</td>
<td width="81%">
<textarea name="text" cols="60" rows="10"></textarea>
</td>
</tr>
<tr bg>
<td width="19%" align="right"> </td>
<td width="81%">
<input type="submit" name="Submit" value="提交">
<input type="reset" name="Submit2" value="重填">
</td>
</tr>
</form>
</table>
</body>
</html>

七、总结

到这里我们就建立一个简单并有分页功能的XML留言本了,呵看完了简单吧,其实我这里只起一个抛砖引玉的功能,其目的是引导大家建立更复杂更好的ASP+XML程序,例如:所上面的留言本加上回复功能,管理功能,点击计数据功能等,甚至你可以把它变一个BBS等等。最后留言本运行结果如下:


(List.xml在IE5下面的运行结果)



(留言本index.asp运行结果)





(PostNew.asp运得结果)



相关推荐

  • DreamweaverMX打造留言本二 在前面我们提到,先要保证留言的正常显示就要做到在有留言的时候才显示留言,如果没有留言则显示“暂无留言”,那这些在DWMX里怎么做呢??在这里呢,我们要学习一个新的服务器行为showregion(显示区域),即根据库里的资料来显示不同的资料。
  • 用DW MX打造基于ACCESS的ASP.NET留言本 1 第一章ASP.NET简介(谈谈我的见解)近来不断地有网友要求写一篇ASP.NET方面的教程,故此抽时间出了这部用DWMX打造ASP.NET留言本的教程,功能不是很强,但是初学者或具有一定的DW-MXASP程序开发经验者入门课程。我不敢保证你
  • flash留言本教程 flash留言本教程 刚开始做这个留言本的时候,连Mysql和PHP都没接触过。经过痛苦的查找资料和学习,郁闷了一个星期后完成了我的简单留言本。网上没有比较好的PHP留言本相关教程,我下载的N多源文件都看得云里雾里,而且好多都将代码写在MC
  • 51留言本板论文_ASP 摘要本文分别介绍了ASP概况、VBScript编程语言,ODBC简介,以及留言簿中用户登陆/注册,发表文章,浏览文章,更改个人信息等功能的实现。Internet的迅猛发展,推动了各种网络技术的不断产生和更新,ASP便是在这一条件下产生的,A
  • 27留言本论文_ASP 摘要【关键字】:留言簿,动态网页,脚本语言,ASP,ODBC,VBScript【Keywords】:BBS,dynamic,ScriptLanguage,ASP,ODBC,VBScriptInternet的迅猛发展,推动了各种网络技术的不断
  • 留言本·许祈愿瓶树·博客横幅·鼠标 留言本在http://xwangel.com/apply/申请的,那里有很多留言本的样式,你可以选择一个自己喜欢的.在给大家推荐一个地址http://www.linyiren.com/1/2/reg.asp也不错.申请成功后你会得到一个地址
  • 114啦网址导航留言本注入漏洞 雨林木风的114啦网址导航程序留言文件存在注入漏洞。漏洞文件feedback/feedback.php攻击者利用EXP可以得到管理员帐号和MD5密码。版本:<=1.5EXP如下:<?php$sbcopyright='------
  • 手把手教你用ASP制作留言本 手把手教你用ASP制作留言本作者:cncontinue 时间:2005-08-04 文档类型:原创 来自:蓝色理想浏览统计total:269047|year:82254|Quarter:13859|Month:387|Week:1772|t
  • PHP--学习第一个制作留言本 PHP--学习第一个制作留言本这一课犯过哪些错误呢?1.就是变量写错了.............导致死循环falsetrue鸟语不会这单词真的是郁闷啊falsefalsefalsefalsetruetruetruetruetrue2.就是E
  • 114啦网址导航留言本注入漏洞 雨林木风的114啦网址导航程序留言文件存在注入漏洞。漏洞文件feedback/攻击者利用EXP可以得到管理员帐号和MD5密码。版本:<=EXP如下:
  • Zend Framework 留言本实战 一、环境搭建和ZF安装*[注]本节内容大部分来至ZendFramework官方手册1.1ZendFramework下载ZendFramework使用面向对象的PHP5构建,需要PHP5.1.4或更高版本。请查阅附录系统需求了解更多信息。一旦
  • ASP 留言本 资料来自http://www.zybiye.cn专业毕业设计网摘要Internet的迅猛发展,推动了各种网络技术的不断产生和更新,ASP便是在这一条件下产生的,ASP的出现改变了以往网站是由单纯的HTML语言编写的静态网页所组成的情况,有了

你的评论

就没有什么想说的吗?

最新博客

关于我们 加入传客 媒体报道 帮助中心 传客活动 免责声明 联系我们 移动版 移动应用

©2017传客网    琼ICP备15003173号-2    

本站部分文章来源于互联网,版权归属于原作者。
本站所有转载文章言论不代表本站观点,如是侵犯了原作者的权利请发邮件联系站长(weishubao@126.com),我们收到后立即删除。
站内所有资源仅供学习与参考,请勿用于商业用途,否则产生的一切后果将由您自己承担!

X